最小限のエディタ

Richard Suchenwirth 2003年8月12日——とても多くの機能を持つ「基本的なエディタ」と対照的に、ファイルの読み込みと保存、そしてもちろん編集、それに切り取りと貼り付けと、テキストウィジェットに組み込まれていることが一通りできるだけの、ごく単純なエディタを以下に掲載します。ちょっとした「オンラインヘルプ」も付いています (*^ーﾟ)。

文芸的プログラミング的な説明については、「最小限のエディタの解説」を参照してください。

幾つかの面白い (と私が思う) 追加機能を備える僅かに拡張された最小限のエディタについては、「最小限度に拡張された最小限のエディタ」を参照してください。——Connor Berry

#! /bin/env tclsh

package require Tk

set about "minEd - 最小限のエディタ
2003年 Richard Suchenwirth
F1: ヘルプ
F2: 読み込み
F3: 保存
"
pack [scrollbar .y -command ".t yview"] -side right -fill y
pack [text .t -wrap word -yscrollc ".y set" -undo 1] -side right -fill both -expand 1

bind . <F1> {tk_messageBox -message $about}
bind . <F2> {loadText .t [tk_getOpenFile]}
bind . <F3> {saveText .t [tk_getSaveFile]}

proc loadText {w fn} {
    if {$fn==""} return
    wm title . [file tail $fn]
    set fp [open $fn]
    $w delete 1.0 end
    $w insert end [read $fp]
    close $fp
}

proc saveText {w fn} {
    if {$fn==""} return
    set fp [open $fn w]
    puts -nonewline $fp [$w get 1.0 "end - 1 c"]
    close $fp
}

if {$argc > 0} {
    loadText .t [lindex $argv 0]
} else {
    .t insert end "キー: F1:ヘルプ、F2:読み込み、F3:保存\n"
}
focus -force .t

【トップへ】

公開日：2012年12月21日

このページは、『Tcler's Wiki』の項目「A minimal editor」の日本語訳です (原文のライセンス/ウェブ魚拓)。
この翻訳は、クリエイティブ・コモンズ 表示 - 継承 3.0 (CC BY-SA 3.0)の下で利用可能です。